Text

Im folgenden finden sich ein paar einfache Anwendungen für die Textausgabe, die Beispielen aus der Prescribe-Dokumentation nachempfunden sind. Sie sollen die vielen Möglichkeiten von Prescribe bei der Textgestaltung demonstrieren.

Einfacher Text

Zum Drucken von Text genügt die Anwahl des Zeichensatzes (Kommando CSET) und die Positionierung (Kommando MAP). Die Auswahl der Schrift erfolgt hier implizit durch das Kommando RES: Courier 10 Zeichen pro Zoll.

Prescribe:

EinfacherText.prs

!R! RES; 
 
CSET 0N;
MAP 2, 2;
             TEXT 'Gewünschte Option bitte ankreuzen:', L, U;
BOX .1, -.1; TEXT "   Servolenkung", L;
BOX .1, -.1; TEXT "   Bremskraftverstärker", L;
PAGE; EXIT;

Ausdruck:

Unterstreichungen

In Prescribe kann mit dem Kommando SULP die Art der Unterstreichung frei gewählt werden. Damit lassen sich unterschiedlich dicke oder abweichend positionierte Unterstreichungsstriche erzeugen. Schliesslich kann die Position des Striches nach oben verschoben werden, um eine Überstreichung zu realisieren.

Prescribe:

Unterstreichungen.prs

!R! RES; UNIT C; 
 
SLS 0.8; CSET 0N; FONT 6;
 
MAP 0, 1;
TEXT "Standard Unterstreichung", E, U; TEXT ", ", E;
SULP .2, .1;
TEXT "mit dickerem Strich", N, U; TEXT "und sogar ", E;
SULP -.32, .04;
TEXT "über dem Text", E, U; TEXT "!";
 
EXIT;

Ausdruck:

Rechtsbündiger Text

In Prescribe kann Text automatisch rechtsbündig ausgegeben werden. Das funktioniert auch mit proportionalen Schriften. Die Kästchen werden in einem Makro (Kommando MCRO bis ENDM) definiert, das bei jedem Aufruf (Kommando CALL) beide Kästchen zeichnet.

Prescribe:

RechtsbuendigerText.prs

!R! RES; 
 
MCRO PF;
     MRP .5, 0; BOX .1, -.1; MRP  1.1, 0;
                BOX .1, -.1; MRP -1.6, 0;
ENDM;
 
FONT 10; CSET 0N; SLPI 4;
 
MAP 3, 3; TEXT 'Erfolgreich  Durchgefallen', L, U;
CALL PF;  RTXT 'Optische Prüfung', L;
CALL PF;  RTXT 'Elektrische Prüfung';   
PAGE; EXIT;

Ausdruck:

Gedrehter Text

Auch das Rotieren von Text wird in Prescribe unterstützt. Dabei kann praktisch jeder beliebige Winkel zwischen 0 und 360 Grad verwendet werden.

Prescribe:

GedrehterText.prs

!R! RES; PSRC 1;
 
SFNT "Univers-Md", 14; CSET 0N; 
 
MZP 4, 4;
 
RTTX 15,  " ----- Löwe, 23. Juli – 22. August";
RTTX 45,  " ----- Krebs, 22. Juni – 22. Juli";
RTTX 75,  " ----- Zwillinge, 22. Mai – 21. Juni";
RTTX 105, " ----- Stier, 21. April – 21. Mai";
RTTX 135, " ----- Widder, 21. März – 20. April";
RTTX 165, " ----- Fische, 19. Februar – 20. März";
RTTX 195, " ----- Wassermann, 20. Januar – 18. Februar";
RTTX 225, " ----- Steinbock, 21. Dezember – 19. Januar";
RTTX 255, " ----- Schütze, 23. November – 20. Dezember";
RTTX 285, " ----- Skorpion, 23. Oktober – 22. November";
RTTX 315, " ----- Waage, 23. September – 22. Oktober";
RTTX 345, " ----- Jungfrau, 23. August – 22. September";
 
PAGE; EXIT;

Ausdruck:

Text mit Graumuster

Mit Hilfe von Prescribe-Kommando aus dem Bereich der Vektorgraphik lassen sich auch Texte mit Mustern füllen (Kommandos GPAT und FILL) und gegebenfalls noch umranden (Kommando STRK). Die Schrift wird in diesem Beispiel quasi mit der PCL-Sequenz ausgewählt.

Prescribe:

Graumuster.prs

!R! RES; UNIT C;
 
FSET 1p48v1s3b4148T;
 
NEWP;
PMZP 5, 5; CPTH "GRAUE SCHRIFT";
PMZP 5, 7; CPTH "MIT RAND";
 
SCG; GPAT .8; FILL 1;
 
RPG; STRK;
 
PAGE;
EXIT;

Ausdruck:

Webseiten-Werkzeuge

Benutzer-Werkzeuge

Text

Einfacher Text

Unterstreichungen

Rechtsbündiger Text

Gedrehter Text

Text mit Graumuster

Seiten-Werkzeuge